#
# $Id$
# $HeadURL$
# $Author$
#

INCLUDE(MacroRTIDDSGen)
INCLUDE(MacroCodeGenIdl)

SET(xml_FILE alm_service.xml)
#
# --- Library svcAlmCommon --------------------------------------------------------------------------------
#
SET(SRCS_common
  alm_export.h
  logger.cpp
  logger.h
)

# Generate alm_enums.idl / alm.idl
IF(BUILD_RTI AND BUILD_GRANTLEE)
  CODEGEN_IDL_SVC(SRCS_common ${xml_FILE})
ELSEIF(BUILD_RTI AND NOT BUILD_GRANTLEE)
  # BUILD_GRANTLEE disabled: check for pre-generated files
  IF(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/alm.idl" AND EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/alm_enums.idl")
    MESSAGE(STATUS "BUILD_GRANTLEE disabled: using pre-generated IDL files for alm")
    LIST(APPEND SRCS_common alm.idl alm_enums.idl)
  ELSE()
    MESSAGE(WARNING "BUILD_GRANTLEE disabled but no pre-generated IDL files found for alm. Skipping service.")
  ENDIF()
ENDIF()
# Generate alm_db_impl.cpp/.h, alm_db.h
IF(BUILD_RTI AND BUILD_GRANTLEE)
  CODEGEN_DATABASE(SRCS_common ${xml_FILE})
ENDIF()

# Generate *.cpp/*.hpp from idl
IF(BUILD_RTI AND (BUILD_GRANTLEE OR (EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/alm.idl" AND EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/alm_enums.idl")))
RTIDDSGEN(SRCS_common alm_enums.idl)
RTIDDSGEN(SRCS_common alm.idl)
ENDIF()

# Generate alm_dt[s,c]_types.h, alm_ft[s,c]_types.h
IF(BUILD_RTI AND BUILD_GRANTLEE)
  CODEGEN_TOPIC_TYPEDEFS(SRCS_common ${xml_FILE})
ENDIF()
# Generate alm_[d|f]tc.h
IF(BUILD_RTI AND BUILD_GRANTLEE)
  CODEGEN_CLIENT_TOPICS_IFC(SRCS_common ${xml_FILE})
ELSEIF(BUILD_RTI AND NOT BUILD_GRANTLEE)
  # Check for pre-generated files
  IF(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/alm_dtc.h" AND EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/alm_ftc.h")
    MESSAGE(STATUS "BUILD_GRANTLEE disabled: using pre-generated DTC/FTC files for alm")
    LIST(APPEND SRCS_common alm_dtc.h alm_ftc.h)
  ELSE()
    MESSAGE(WARNING "BUILD_GRANTLEE disabled but no pre-generated DTC/FTC files found for alm")
  ENDIF()
ENDIF()

NGL_ADD_LIBRARY(AAR SV WS svcAlmCommon SHARED  ${SRCS_common})
NGL_TARGET_INCLUDE_DIRECTORIES(svcAlmCommon
  PUBLIC
    ${CMAKE_CURRENT_SOURCE_DIR}/../
    ${CMAKE_CURRENT_BINARY_DIR}/../
)
NGL_TARGET_LINK_LIBRARIES(svcAlmCommon
  PRIVATE
    RTI::nddscpp2
  PUBLIC
    Qt6::Core
    $<IF:$<TARGET_EXISTS:ddscore>,ddscore,>
    NGLLogger
    $<IF:$<TARGET_EXISTS:svcPdmCommon>,svcPdmCommon,>
    ngldb
)
NGL_INSTALL_TARGET(svcAlmCommon)

#
# --- Library svcAlmClient --------------------------------------------------------------------------------
#
SET(SRCS_client
  alm_export.h
)
# generate alm_[d|f]tc.h, tlm_[d|f]tc_impl.[cpp|h]
IF(BUILD_RTI AND BUILD_GRANTLEE)
  CODEGEN_CLIENT_TOPICS_IMPL(SRCS_client ${xml_FILE})
ELSEIF(BUILD_RTI AND NOT BUILD_GRANTLEE)
  # Check for pre-generated files
  IF(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/alm_dtc.h" AND EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/alm_ftc.h")
    MESSAGE(STATUS "BUILD_GRANTLEE disabled: using pre-generated DTC/FTC files for alm client")
    LIST(APPEND SRCS_client alm_dtc.h alm_ftc.h)
  ELSE()
    MESSAGE(WARNING "BUILD_GRANTLEE disabled but no pre-generated DTC/FTC files found for alm client")
  ENDIF()
ENDIF()

NGL_ADD_LIBRARY(AAR SV WS svcAlmClient SHARED ${SRCS_client})
NGL_TARGET_INCLUDE_DIRECTORIES(svcAlmClient
  PUBLIC
    ${CMAKE_CURRENT_SOURCE_DIR}/../
    ${CMAKE_CURRENT_BINARY_DIR}/../
)

NGL_TARGET_LINK_LIBRARIES(svcAlmClient
  PRIVATE
    RTI::nddscpp2
    $<IF:$<TARGET_EXISTS:ddsconnector>,ddsconnector,>
  PUBLIC
    svcAlmCommon
    ddsftc

)
NGL_INSTALL_TARGET(svcAlmClient)

#
# --- Library svcAlmServer --------------------------------------------------------------------------------
#
SET(SRCS_server
  alm_export.h
  dds_handler.cpp
  dds_handler.h
  handler_configure_alarms.cpp
  handler_configure_alarms.h
  handler_participant.cpp
  handler_participant.h
  handler_emergency_call.cpp
  handler_emergency_call.h
  initialization.cpp
  initialization.h
  object_emergency_call.cpp
  object_emergency_call.h
#  settings.cpp
#  settings.h
)
# generate alm_[d|f]ts.h, alm_[d|f]ts_impl.[cpp|h]
IF(BUILD_RTI)
  CODEGEN_SERVER_TOPICS(SRCS_server ${xml_FILE})
ENDIF()
# Generate alm.sql, alm.xml
IF(BUILD_RTI)
  CODEGEN_SQL(SRCS_server ${xml_FILE})
ENDIF()

NGL_ADD_LIBRARY(AAR SV svcAlmServer SHARED ${SRCS_server})
NGL_TARGET_INCLUDE_DIRECTORIES(svcAlmServer
  PUBLIC
    ${CMAKE_CURRENT_SOURCE_DIR}/../
    ${CMAKE_CURRENT_BINARY_DIR}/../
)

NGL_TARGET_LINK_LIBRARIES(svcAlmServer
  PRIVATE
    RTI::nddscpp2
    Qt6::Core
    ddsfts
    $<IF:$<TARGET_EXISTS:ddsconnector>,ddsconnector,>
    ddsQoS
    $<IF:$<TARGET_EXISTS:svcPdmCommon>,svcPdmCommon,>
    svcAlmCommon
    svcAlmClient
    svcEemClient
    svcPpmClient
    svcMrkClient
    svcCoreClient
    svcTabClient
    svcExmClient
    svcTabServer
    nglsettings
    NGLLogger
    $<IF:$<TARGET_EXISTS:ddscore>,ddscore,>
    ngltools
  PUBLIC
    svcAlmCommon
    ngldb
)
NGL_INSTALL_TARGET(svcAlmServer)

#
# --- Topic Type Plugin --------------------------------------------------------------
#
IF(BUILD_RTI)
  CREATE_TOPIC_TYPE_PLUGIN(${xml_FILE})
ENDIF()

#
# --- RecordReplayPlugin --------------------------------------------------------------
#
CREATE_RECORD_REPLAY_PLUGIN(${xml_FILE} SRCS_server)


# Uncomment if necessary
#ADD_SUBDIRECTORY(UnitTests)
ADD_SUBDIRECTORY(ModuleTests)
