#
# $Id$
# $HeadURL$
# $Author$
#

# Uncomment if necessary
#ADD_SUBDIRECTORY(UnitTests)
#ADD_SUBDIRECTORY(ModuleTests)

# Make ${Qt6_Gui} optional
if(QT6_GUI_AVAILABLE AND TARGET Qt6::Gui)
  set(Qt6_Gui ${Qt6_Gui})
else()
  set(Qt6_Gui "")
endif()


ADD_SUBDIRECTORY(Plugins)

SET(xml_FILE tab_service.xml)

#
# --- Library tabTelegrams --------------------------------------------------------------------------------
#
find_package(Qt6 COMPONENTS Core Sql Network REQUIRED)
set(_QT_CORE_TARGET Qt6::Core)
set(_QT_SQL_TARGET Qt6::Sql)
set(_QT_NETWORK_TARGET Qt6::Network)

SET(SRCS_telegrams
  training_area_telegrams.cpp
  training_area_telegrams.h
)
NGL_ADD_LIBRARY(AAR SV WS HLA tabTelegrams STATIC ${SRCS_telegrams})

# tabTelegrams is a STATIC lib linked into shared/MODULE targets
SET_TARGET_PROPERTIES(tabTelegrams PROPERTIES POSITION_INDEPENDENT_CODE ON)
NGL_TARGET_INCLUDE_DIRECTORIES(tabTelegrams
  PUBLIC
    ${CMAKE_CURRENT_SOURCE_DIR}/..
)
NGL_TARGET_LINK_LIBRARIES(tabTelegrams
  PUBLIC
    ${_QT_CORE_TARGET}
    $<IF:$<AND:$<BOOL:${QT6_GUI_AVAILABLE}>,$<TARGET_EXISTS:Qt6::Gui>>,Qt6::Gui,>
    ${_QT_NETWORK_TARGET}
)

# install on RPM build and copy for local builds so that LogView automatically finds the training_area_telegrams.h file
if (BUILD_RPM)
  add_custom_target(training_area_telegrams.h_bin) # empty target so that LogView still builds on RPM build
  NGL_INSTALL(AAR SV FILES training_area_telegrams.h DESTINATION bin)
else()
  add_custom_command(
    OUTPUT ${CMAKE_BINARY_DIR}/bin/training_area_telegrams.h
    COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/training_area_telegrams.h ${CMAKE_BINARY_DIR}/bin/training_area_telegrams.h
    DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/training_area_telegrams.h
    COMMENT "[Local build] Copy training_area_telegrams.h for LogView into bin/"
  )
  add_custom_target(training_area_telegrams.h_bin DEPENDS ${CMAKE_BINARY_DIR}/bin/training_area_telegrams.h)
endif()

#
# --- Library svcTabCommon --------------------------------------------------------------------------------
#
SET(SRCS_common
  logger.cpp
  logger.h
  tab_export.h
)

# Stub files (no RTI code generation in the release scope)
LIST(APPEND SRCS_common
  stubs/tab_enums_stub.hpp
  stubs/tab_stub.hpp
  stubs/tab_db_stub.hpp
  stubs/tab_topic_type_plugin_stub.cpp
)

# Create target only if component flags allow
NGL_ADD_LIBRARY2(AAR SV WS HLA svcTabCommon SHARED  ${SRCS_common})

IF(NOT TARGET svcTabCommon)
  # Create a dummy static library just for export header generation
  ADD_LIBRARY(svcTabCommon STATIC ${SRCS_common})
ENDIF()
GENERATE_EXPORT_HEADER(svcTabCommon EXPORT_FILE_NAME "svctabcommon_export.h")

NGL_TARGET_INCLUDE_DIRECTORIES(svcTabCommon
  PUBLIC
    ${CMAKE_CURRENT_SOURCE_DIR}/../
    ${CMAKE_CURRENT_BINARY_DIR}
    ${CMAKE_CURRENT_SOURCE_DIR}/stubs
)
NGL_TARGET_LINK_LIBRARIES(svcTabCommon
  PUBLIC
    Qt6::Core
    $<IF:$<AND:$<BOOL:${QT6_GUI_AVAILABLE}>,$<TARGET_EXISTS:Qt6::Gui>>,Qt6::Gui,>
    Qt6::Sql
    Qt6::Network
    NGLLogger
    ngldb
    $<IF:$<TARGET_EXISTS:svcPdmCommon>,svcPdmCommon,>
    LtsUtilsCoreHeaderOnly
)
NGL_INSTALL_TARGET(svcTabCommon)

# clientPluginInterface
ADD_LIBRARY(tabPluginInterface INTERFACE)
TARGET_SOURCES(tabPluginInterface INTERFACE
  ${CMAKE_CURRENT_SOURCE_DIR}/tab_plugin_interface.h
  ${CMAKE_CURRENT_SOURCE_DIR}/training_area_telegrams.h
)
TARGET_INCLUDE_DIRECTORIES(tabPluginInterface INTERFACE ${CMAKE_CURRENT_SOURCE_DIR}/../)
TARGET_LINK_LIBRARIES(tabPluginInterface INTERFACE Qt6::Core $<IF:$<TARGET_EXISTS:svcPdmCommon>,svcPdmCommon,>)
