qt-migration-legatus/qt5-before/dlbo/Lts/Services/OcSituationClient/CMakeLists.txt

#
# $Id$
# $HeadURL$
# $Author$
#

INCLUDE(MacroRTIDDSGen)
INCLUDE(MacroCodeGenIdl)

SET(xml_FILE osc_service.xml)

#
# --- Library svcOscCommon --------------------------------------------------------------------------------
#
SET(SRCS_common
  osc_export.h
  logger.cpp
  logger.h
)

# copy osc_predefined_data.sql to share
SET(in_file_sql  "osc_predefined_data.sql")
SET(out_dir_sql  "${CMAKE_BINARY_DIR}/share/Lts/sql/")
SET(out_file_sql "${out_dir_sql}/${in_file_sql}")
ADD_CUSTOM_COMMAND(OUTPUT ${out_file_sql}
                   COMMAND ${CMAKE_COMMAND}
                     ARGS -E make_directory ${out_dir_sql}
                   COMMAND ${CMAKE_COMMAND}
                     ARGS -E copy_if_different ${in_file_sql} ${out_file_sql}
                   DEPENDS ${in_file_sql}
                   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
                   )

# Generate osc_enums.idl / osc.idl
CODEGEN_IDL_SVC(SRCS_common ${xml_FILE})
# Generate osc_db_impl.cpp/.h, osc_db.h
CODEGEN_DATABASE(SRCS_common ${xml_FILE})

# Generate *.cpp/*.hpp from idl
RTIDDSGEN(SRCS_common osc_enums.idl)
RTIDDSGEN(SRCS_common osc.idl)

# Generate osc_dt[s,c]_types.h, osc_ft[s,c]_types.h
CODEGEN_TOPIC_TYPEDEFS(SRCS_common ${xml_FILE})
# Generate osc_[d|f]tc.h
CODEGEN_CLIENT_TOPICS_IFC(SRCS_common ${xml_FILE} PARTS FTC)

NGL_ADD_LIBRARY(SV WS svcOscCommon SHARED  ${SRCS_common})
NGL_TARGET_INCLUDE_DIRECTORIES(svcOscCommon
  PUBLIC
    ${CMAKE_CURRENT_SOURCE_DIR}/../
    ${CMAKE_CURRENT_BINARY_DIR}/../
)
NGL_TARGET_LINK_LIBRARIES(svcOscCommon
  PRIVATE
    RTI::nddscpp2
  PUBLIC
    Qt5::Core
    ddscore
    NGLLogger
    ngldb
)
NGL_INSTALL_TARGET(svcOscCommon)

#
# --- Library svcOscClient --------------------------------------------------------------------------------
#
SET(SRCS_client
  osc_export.h
)
# generate osc_[d|f]tc.h, osc_[d|f]tc_impl.[cpp|h]
CODEGEN_CLIENT_TOPICS_IMPL(SRCS_client ${xml_FILE} PARTS FTC)

NGL_ADD_LIBRARY(SV WS svcOscClient SHARED ${SRCS_client})
NGL_TARGET_INCLUDE_DIRECTORIES(svcOscClient
  PUBLIC
    ${CMAKE_CURRENT_SOURCE_DIR}/../
    ${CMAKE_CURRENT_BINARY_DIR}/../
)

NGL_TARGET_LINK_LIBRARIES(svcOscClient
  PRIVATE
    RTI::nddscpp2
    ddsconnector
  PUBLIC
    svcOscCommon
    ddsftc
)
NGL_INSTALL_TARGET(svcOscClient)

#
# --- Library svcOscServer --------------------------------------------------------------------------------
#
SET(SRCS_server
  osc_export.h
)
# generate osc_[d|f]ts.h, osc_[d|f]ts_impl.[cpp|h]
CODEGEN_SERVER_TOPICS(SRCS_server ${xml_FILE} PARTS FTS)

NGL_ADD_LIBRARY(SV svcOscServer SHARED ${SRCS_server})
NGL_TARGET_INCLUDE_DIRECTORIES(svcOscServer
  PUBLIC
    ${CMAKE_CURRENT_SOURCE_DIR}/../
    ${CMAKE_CURRENT_BINARY_DIR}/../
)

NGL_TARGET_LINK_LIBRARIES(svcOscServer
  PRIVATE
    RTI::nddscpp2
    ddsconnector
    ddsfts
  PUBLIC
    svcOscCommon
    ngldb
)
NGL_INSTALL_TARGET(svcOscServer)

#
# --- Topic Type Plugin --------------------------------------------------------------
#
CREATE_TOPIC_TYPE_PLUGIN(${xml_FILE})

#
# --- Executable svcOcSituationClient (sOSC) -------------------------------------------------
#
SET(SRCS_exe
  central_aes_byte_reader.h
  central_aes_byte_reader.cpp
  main.cpp
  main_handler.cpp
  main_handler.h
  dds_handler.cpp
  dds_handler.h
  handler_oc_aes_data.cpp
  handler_oc_aes_data.h
  handler_oc_central_aes_data.cpp
  handler_oc_central_aes_data.h
  handler_oc_data.cpp
  handler_oc_data.h
  handler_oc_situation_data.cpp
  handler_oc_situation_data.h
  settings.cpp
  settings.h

  ${xml_FILE}
)

# Generate osc.sql, osc.xml
CODEGEN_SQL(SRCS_exe ${xml_FILE})

NGL_ADD_SVC_ICON(SRCS_exe)
NGL_ADD_EXECUTABLE(SV svcOcSituationClient ${SRCS_exe})
NGL_TARGET_LINK_LIBRARIES(svcOcSituationClient
  Qt5::Core
  svcOscCommon
  svcOscServer
  svcCoreClient
  svcAesClient
  svcEvlClient
  svcGimClient
  svcMsgClient
  svcOpmClient
  svcOssServer
  svcPpmClient
  svcTabClient
  svcTabServer
  svcTabocClient
  svcTabocServer
  ddsconnector
  nglsettings
  ProjectConfig
  LtsCommandLineParser
  LtsCoordTrans
  LtsUtilsCoreHeaderOnly
  NGLLogger
  nglcoreapplication
  ngltools
)
NGL_INSTALL_TARGET(svcOcSituationClient)
NGL_INSTALL(SV FILES log4cxx_osc.props DESTINATION bin)
NGL_ADD_TARGET_LINK(svcOcSituationClient sOSC)

# Uncomment if necessary
#ADD_SUBDIRECTORY(UnitTests)
#ADD_SUBDIRECTORY(ModuleTests)