# -------------------------------------------------------------------------
# $HeadURL$
# -------------------------------------------------------------------------
#!
# -------------------------------------------------------------------------
# COPYRIGHT (C) 2017: RHEINMETALL ELECTRONICS GmbH, D-28305 BREMEN
# -------------------------------------------------------------------------
#
# Revision INFO:
# --------------
#   $Revision$
#   $Date$
#   $Id$
#
# PURPOSE:
# --------
# Suchen der KDReports-Library und Setzen der folgenden CMake-Variablen:
# KDREPORTS_INCLUDE_DIRS - KDReports headers location
# KDREPORTS_LIBRARY      - KDReports library
# KDREPORTS_FOUND        - TRUE wenn Library gefunden wurde
#

FIND_PACKAGE(Qt5 COMPONENTS Core Gui PrintSupport Sql Svg Widgets Xml REQUIRED)
IF(KDREPORTS_INCLUDE_DIR AND KDREPORTS_KDREPORTS_INCLUDE_DIR AND KDREPORTS_LIBRARY)
  SET(KDREPORTS_FOUND TRUE)
ELSE()

  FIND_PATH(KDREPORTS_INCLUDE_DIR   KDReports/KDReports.h)
  FIND_PATH(KDREPORTS_KDREPORTS_INCLUDE_DIR KDReports.h PATH_SUFFIXES KDReports)
  FIND_LIBRARY(KDREPORTS_LIBRARY NAMES kdreports)

  INCLUDE(FindPackageHandleStandardArgs)
  FIND_PACKAGE_HANDLE_STANDARD_ARGS(KDReports DEFAULT_MSG
                                    KDREPORTS_LIBRARY
                                    KDREPORTS_INCLUDE_DIR
                                    KDREPORTS_KDREPORTS_INCLUDE_DIR
                                    )

  MARK_AS_ADVANCED(KDREPORTS_INCLUDE_DIR KDREPORTS_LIBRARY)
  MARK_AS_ADVANCED(KDREPORTS_KDREPORTS_INCLUDE_DIR KDREPORTS_LIBRARY)
ENDIF()

IF(NOT TARGET KDReports::KDReports)
  ADD_LIBRARY(KDReports::KDReports UNKNOWN IMPORTED)
  SET_PROPERTY(TARGET KDReports::KDReports PROPERTY INTERFACE_INCLUDE_DIRECTORIES        "${KDREPORTS_INCLUDE_DIR}" "${KDREPORTS_KDREPORTS_INCLUDE_DIR}")
  SET_PROPERTY(TARGET KDReports::KDReports PROPERTY INTERFACE_SYSTEM_INCLUDE_DIRECTORIES "${KDREPORTS_INCLUDE_DIR}" "${KDREPORTS_KDREPORTS_INCLUDE_DIR}") # -isystem
  SET_PROPERTY(TARGET KDReports::KDReports PROPERTY IMPORTED_LOCATION                    "${KDREPORTS_LIBRARY}")
  SET_PROPERTY(TARGET KDReports::KDReports APPEND PROPERTY INTERFACE_LINK_LIBRARIES Qt5::Core Qt5::Gui Qt5::PrintSupport Qt5::Widgets)
ENDIF()