# - Try to find the poppler PDF library
# Once done this will define
#
#  POPPLER_QT5_FOUND - system has poppler
#  POPPLER_QT5_INCLUDE_DIR - the poppler include directory
#  POPPLER_QT5_LIBRARY - Link this to use poppler
#

# Copyright (c) 2006-2010, Pino Toscano, <pino@kde.org>
#
# Redistribution and use is allowed according to the terms of the BSD license.
# For details see the accompanying COPYING-CMAKE-SCRIPTS file.

if(POPPLER_QT5_INCLUDE_DIR AND POPPLER_QT5_LIBRARY)

  # in cache already
  set(POPPLER_QT5_FOUND TRUE)

else(POPPLER_QT5_INCLUDE_DIR AND POPPLER_QT5_LIBRARY)

set(_poppler_version_bad FALSE)

if(NOT WIN32)
  # use pkg-config to get the directories and then use these values
  # in the FIND_PATH() and FIND_LIBRARY() calls
  include(FindPkgConfig)
  pkg_check_modules(_pc_poppler poppler-qt5)
  if(_pc_poppler_FOUND)
    if(NOT "${_pc_poppler_VERSION}" VERSION_GREATER 0.24.0)
      set(_poppler_version_bad TRUE)
    endif(NOT "${_pc_poppler_VERSION}" VERSION_GREATER 0.24.0)
  endif(_pc_poppler_FOUND)
endif(NOT WIN32)

if(NOT _poppler_version_bad)
  set(POPPLER_QT5_FOUND FALSE)

  find_library(POPPLER_QT5_LIBRARY poppler-qt5
               HINTS ${_pc_poppler_LIBRARY_DIRS}
  )

  find_path(POPPLER_QT5_INCLUDE_DIR poppler-qt5.h
            HINTS ${_pc_poppler_INCLUDE_DIRS}
            PATH_SUFFIXES poppler/qt5
  )
  find_path(POPPLER_QT5_INCLUDE_DIR_core qt5/poppler-qt5.h
            HINTS ${_pc_poppler_INCLUDE_DIRS}
            PATH_SUFFIXES poppler
  )

  if(POPPLER_QT5_LIBRARY AND POPPLER_QT5_INCLUDE_DIR AND POPPLER_QT5_INCLUDE_DIR_core)
    list(APPEND POPPLER_QT5_INCLUDE_DIR "${POPPLER_QT5_INCLUDE_DIR_core}")
    set(POPPLER_QT5_FOUND TRUE)
  endif(POPPLER_QT5_LIBRARY AND POPPLER_QT5_INCLUDE_DIR AND POPPLER_QT5_INCLUDE_DIR_core)
endif(NOT _poppler_version_bad)

INCLUDE(FindPackageHandleStandardArgs)
FIND_PACKAGE_HANDLE_STANDARD_ARGS(PopplerQt5 DEFAULT_MSG
                                  POPPLER_QT5_LIBRARY
                                  POPPLER_QT5_INCLUDE_DIR)
endif(POPPLER_QT5_INCLUDE_DIR AND POPPLER_QT5_LIBRARY)