torstenandCopilot
342ffd3e5c
- HandlerMinelayerData: BUILD_RTI Guards für RTI-Abhängigkeiten - svcTabCommon: Export-Header-Fix via Fallback-Target - TrainingAreaBase: Stub-Header für BUILD_RTI=OFF - ddsfts: Include-Pfad und Dependency-Fixes - BUILD_RTI=OFF Compilation vollständig unterstützt Co-authored-by: Copilot <223556219+Copilot@users.noreply.github.com> Entire-Checkpoint: 01M0JNZA586SACX1PRZ2DJAE5S
98 lines
4.1 KiB
CMake
98 lines
4.1 KiB
CMake
# Configure GeographicLib
|
|
#
|
|
# Set
|
|
# GeographicLib_FOUND = TRUE
|
|
# GeographicLib_INCLUDE_DIRS = /usr/local/include
|
|
# GeographicLib_SHARED_LIBRARIES = GeographicLib_SHARED (or empty)
|
|
# GeographicLib_STATIC_LIBRARIES = GeographicLib_STATIC (or empty)
|
|
# GeographicLib_LIBRARY_DIRS = /usr/local/lib
|
|
# GeographicLib_BINARY_DIRS = /usr/local/bin
|
|
# GeographicLib_VERSION = 1.34 (for example)
|
|
# GEOGRAPHICLIB_DATA = /usr/local/share/GeographicLib (for example)
|
|
# Depending on GeographicLib_USE_STATIC_LIBS
|
|
# GeographicLib_LIBRARIES = ${GeographicLib_SHARED_LIBRARIES}, if OFF
|
|
# GeographicLib_LIBRARIES = ${GeographicLib_STATIC_LIBRARIES}, if ON
|
|
# If only one of the libraries is provided, then
|
|
# GeographicLib_USE_STATIC_LIBS is ignored.
|
|
#
|
|
# Since cmake 2.8.11 or later, there's no need to include
|
|
# include_directories (${GeographicLib_INCLUDE_DIRS})
|
|
# The variables are retained for information.
|
|
#
|
|
# The following variables are only relevant if the library has been
|
|
# compiled with a default precision different from double:
|
|
# GEOGRAPHICLIB_PRECISION = the precision of the library (usually 2)
|
|
# GeographicLib_HIGHPREC_LIBRARIES = the libraries need for high precision
|
|
|
|
message (STATUS "Reading ${CMAKE_CURRENT_LIST_FILE}")
|
|
# GeographicLib_VERSION is set by version file
|
|
message (STATUS
|
|
"GeographicLib configuration, version ${GeographicLib_VERSION}")
|
|
|
|
# Tell the user project where to find our headers and libraries
|
|
get_filename_component (_DIR ${CMAKE_CURRENT_LIST_FILE} PATH)
|
|
if (IS_ABSOLUTE "../../..")
|
|
# This is an uninstalled package (still in the build tree)
|
|
set (_ROOT "../../..")
|
|
set (GeographicLib_INCLUDE_DIRS "")
|
|
set (GeographicLib_LIBRARY_DIRS "${_ROOT}/src")
|
|
set (GeographicLib_BINARY_DIRS "${_ROOT}/tools")
|
|
else ()
|
|
# This is an installed package; figure out the paths relative to the
|
|
# current directory.
|
|
get_filename_component (_ROOT "${_DIR}/../../.." ABSOLUTE)
|
|
set (GeographicLib_INCLUDE_DIRS "${_ROOT}/include")
|
|
set (GeographicLib_LIBRARY_DIRS "${_ROOT}/lib")
|
|
set (GeographicLib_BINARY_DIRS "${_ROOT}/bin")
|
|
endif ()
|
|
set (GEOGRAPHICLIB_DATA "/usr/local/share/GeographicLib")
|
|
set (GEOGRAPHICLIB_PRECISION 2)
|
|
set (GeographicLib_HIGHPREC_LIBRARIES "")
|
|
|
|
set (GeographicLib_SHARED_LIBRARIES GeographicLib::GeographicLib_SHARED)
|
|
set (GeographicLib_STATIC_LIBRARIES )
|
|
# Read in the exported definition of the library
|
|
include ("${_DIR}/geographiclib-targets.cmake")
|
|
|
|
# For interoperability with older installations of GeographicLib and
|
|
# with packages which depend on GeographicLib, GeographicLib_LIBRARIES
|
|
# etc. still point to the non-namespace variables. Tentatively plan to
|
|
# transition to namespace variables as follows:
|
|
#
|
|
# * namespace targets were introduced with version 1.47 (2017-02-15)
|
|
# * switch GeographicLib_LIBRARIES to point to namespace variable after
|
|
# 2020-02
|
|
# * remove non-namespace variables after 2023-02
|
|
|
|
unset (_ROOT)
|
|
unset (_DIR)
|
|
|
|
if ((NOT GeographicLib_SHARED_LIBRARIES) OR
|
|
(GeographicLib_USE_STATIC_LIBS AND GeographicLib_STATIC_LIBRARIES))
|
|
set (GeographicLib_LIBRARIES ${GeographicLib_STATIC_LIBRARIES})
|
|
message (STATUS " \${GeographicLib_LIBRARIES} set to static library")
|
|
else ()
|
|
set (GeographicLib_LIBRARIES ${GeographicLib_SHARED_LIBRARIES})
|
|
message (STATUS " \${GeographicLib_LIBRARIES} set to shared library")
|
|
endif ()
|
|
|
|
# Check for the components requested. This only supports components
|
|
# STATIC and SHARED by checking the value of
|
|
# GeographicLib_${comp}_LIBRARIES. No need to check if the component
|
|
# is required or not--the version file took care of that.
|
|
# GeographicLib_${comp}_FOUND is set appropriately for each component.
|
|
if (GeographicLib_FIND_COMPONENTS)
|
|
foreach (comp ${GeographicLib_FIND_COMPONENTS})
|
|
if (GeographicLib_${comp}_LIBRARIES)
|
|
set (GeographicLib_${comp}_FOUND TRUE)
|
|
message (STATUS "GeographicLib component ${comp} found")
|
|
else ()
|
|
set (GeographicLib_${comp}_FOUND FALSE)
|
|
message (WARNING "GeographicLib component ${comp} not found")
|
|
endif ()
|
|
endforeach ()
|
|
endif ()
|
|
|
|
# GeographicLib_FOUND is set to TRUE automatically
|
|
set (GEOGRAPHICLIB_FOUND TRUE) # for backwards compatibility, deprecated
|